Aquí un ejemplo con un objeto OLE RTF y texto formateado, para ser impreso desde el método Click del CommandButton

PUBLIC loMiForm
loMiForm = NEWOBJECT("MiForm")
loMiForm.SHOW
RETURN

DEFINE CLASS MiForm AS FORM
  HEIGHT = 260
  WIDTH = 500
  AUTOCENTER = .T.
  CAPTION = "Ejemplo de impresion RTF"
  NAME = "MiForm"

  ADD OBJECT oleRTF AS OLECONTROL WITH ;
    TOP = 24, LEFT = 24, HEIGHT = 216, WIDTH = 372, ;
    NAME = "oleRTF", OLECLASS = "RICHTEXT.RichtextCtrl.1"

  ADD OBJECT cmdPrint AS COMMANDBUTTON WITH ;
    TOP = 24, LEFT = 408, HEIGHT = 37, WIDTH = 72, ;
    CAPTION = "Imprimir", NAME = "cmdPrint"

  PROCEDURE INIT
    TEXT TO lcRTF NOSHOW PRETEXT 2
{\rtf1\ansi\ansicpg1252\deff0\deflang11274{\fonttbl{\f0\fswiss\fcharset0 Arial;}
{\f1\fswiss\fprq2\fcharset0 Arial Black;}{\f2\fswiss\fprq2\fcharset0 Arial Narrow;}}
{\colortbl ;\red255\green0\blue0;\red0\green0\blue255;}
{\*\generator Msftedit 5.41.21.2507;}
\viewkind4\uc1\pard\ul\b\f0\fs40 Ejemplo de \cf1 RTF\cf0\ulnone\b0\fs20\par
\par
\cf2\i\f1\fs72 PortalFox\cf0\f0\fs20\par
\b\f2\fs36 Nada corre como un zorro\b0\i0\f0\fs20\par
\par
}
    ENDTEXT
    ERASE "RTF.RTF"
    STRTOFILE(lcRTF, "RTF.RTF")
    THISFORM.oleRTF.FileName = "RTF.RTF"
  ENDPROC

  PROCEDURE cmdPrint.CLICK
    *-- Respuesta de Anders
    DECLARE INTEGER CreateDC IN Win32Api ;
      STRING, STRING, INTEGER, INTEGER
    DECLARE INTEGER DeleteDC IN Win32Api INTEGER
    cPrinter = SET("PRINTER",3)
    hDC = CreateDC("WINSPOOL",cPrinter,0,0)
    THISFORM.oleRTF.SelPrint(hDC)
    DeleteDC(hDC)
  ENDPROC

ENDDEFINE